_span.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
primitive SpanShuffle
  """
  Shuffle operations.
  """
  fun string(): String iso^ => "shuffle".clone()

primitive SpanFilter
  """
  Filter rejection spans.
  """
  fun string(): String iso^ => "filter".clone()

primitive SpanElement
  """
  Collection element spans.
  """
  fun string(): String iso^ => "element".clone()

type SpanLabel is (SpanShuffle | SpanFilter | SpanElement)
  """
  Labels that identify what kind of structure a span represents.
  Pass one to `Randomness.start_span` when building custom generators.
  """

class val _Span is (Equatable[_Span] & Stringable)
  let start_index: USize
  let end_index: USize
  let label: SpanLabel
  let discarded: Bool

  new val create(
    start_index': USize,
    end_index': USize,
    label': SpanLabel,
    discarded': Bool = false)
  =>
    start_index = start_index'
    end_index = end_index'
    label = label'
    discarded = discarded'

  fun eq(other: box->_Span): Bool =>
    (start_index == other.start_index) and
      (end_index == other.end_index) and
      (label is other.label) and
      (discarded == other.discarded)

  fun string(): String iso^ =>
    recover
      String()
        .> append("Span(")
        .> append(start_index.string())
        .> append("..")
        .> append(end_index.string())
        .> append(", ")
        .> append(label.string())
        .> append(if discarded then ", discarded" else "" end)
        .> append(")")
    end