process_error.pony

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
class val ProcessError
  """
  Why a process could not be started, or why monitoring one failed.
  `StartProcess` returns a `ProcessError` when it cannot start a process, and
  `ProcessNotify.failed` receives one for errors that arise while a process
  runs. `error_type` is the category of the error; `message` is optional
  human-readable detail.
  """
  let error_type: ProcessErrorType
  let message: (String | None)

  new val create(error_type': ProcessErrorType,
    message': (String | None) = None)
  =>
    error_type = error_type'
    message = message'

  fun string(): String iso^ =>
    match message
    | let m: String =>
      recover
        let etc = error_type.string()
        let len = etc.size() + 2 + m.size()
        String(len)
          .> append(consume etc)
          .> append(": ")
          .> append(m)
      end
    else
      error_type.string()
    end

type ProcessErrorType is
  ( ExecveError
  | ExecutableNotFound
  | UnsupportedKernel
  | PipeError
  | ForkError
  | WaitpidError
  | WriteError
  | KillError
  | CapError
  | ChdirError
  | UnknownError
  )
  """
  The category of a `ProcessError`.
  """

primitive ExecveError
  """
  `execve` failed in the child after the process was started, so the program
  never ran. Arrives through `ProcessNotify.failed`. For a path that does not
  name a runnable file in the first place, see `ExecutableNotFound`.
  """
  fun string(): String iso^ => "ExecveError".clone()

primitive ExecutableNotFound
  """
  The path given to start a process does not name an existing file we can try
  to execute; it is missing or is a directory. Distinct from `ExecveError`,
  which is `execve` failing in the child after the process was started.
  """
  fun string(): String iso^ => "ExecutableNotFound".clone()

primitive UnsupportedKernel
  """
  The platform cannot report a child's exit. On Linux this means the kernel is
  older than 5.3 and lacks `pidfd_open`.
  """
  fun string(): String iso^ => "UnsupportedKernel".clone()

primitive PipeError
  """
  A pipe to communicate with the child could not be opened. Returned by
  `StartProcess`.
  """
  fun string(): String iso^ => "PipeError".clone()

primitive ForkError
  """
  The child process could not be created (`fork` on posix, `CreateProcess` on
  Windows). Returned by `StartProcess`.
  """
  fun string(): String iso^ => "ForkError".clone()

primitive WaitpidError
  """
  The child's exit status could not be read. Arrives through
  `ProcessNotify.failed` as a terminal error in place of `dispose`.
  """
  fun string(): String iso^ => "WaitpidError".clone()

primitive WriteError
  """
  Writing to the child's STDIN failed. Arrives through `ProcessNotify.failed`.
  """
  fun string(): String iso^ => "WriteError".clone()

primitive KillError
  """
  Currently unused.
  """
  fun string(): String iso^ => "KillError".clone()

primitive CapError
  """
  The path does not have the `FileExec` capability, so we are not permitted to
  execute it. Returned by `StartProcess`.
  """
  fun string(): String iso^ => "CapError".clone()

primitive ChdirError
  """
  The child could not change to the requested working directory. Arrives
  through `ProcessNotify.failed`.
  """
  fun string(): String iso^ => "ChdirError".clone()

primitive UnknownError
  """
  The child reported a startup failure we could not classify. Arrives through
  `ProcessNotify.failed`.
  """
  fun string(): String iso^ => "UnknownError".clone()