max_spawn.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
use "constrained_types"

primitive MaxSpawnValidator is Validator[U32]
  """
  Validates that a max spawn value is at least 1.

  A limit of 0 is nonsensical — it would prevent any connections from being
  accepted. Used by `MakeMaxSpawn` to construct `MaxSpawn` values.
  """
  fun apply(value: U32): ValidationResult =>
    if value == 0 then
      recover val
        ValidationFailure("max spawn must be greater than zero")
      end
    else
      ValidationSuccess
    end

type MaxSpawn is Constrained[U32, MaxSpawnValidator]
  """
  A validated maximum number of concurrent connections. The value must be
  at least 1.

  Construct with `MakeMaxSpawn(count)`, which returns
  `(MaxSpawn | ValidationFailure)`. Pass to `TCPListener` via the `limit`
  parameter, or pass `None` to disable the connection limit.
  """

type MakeMaxSpawn is MakeConstrained[U32, MaxSpawnValidator]
  """
  Factory for `MaxSpawn` values. Returns `(MaxSpawn | ValidationFailure)`.
  """

primitive DefaultMaxSpawn
  """
  Returns a `MaxSpawn` with the default connection limit of 100,000.
  """
  fun apply(): MaxSpawn =>
    match \exhaustive\ MakeMaxSpawn(100_000)
    | let m: MaxSpawn => m
    | let _: ValidationFailure =>
      // Known unreachable: 100,000 is always valid.
      _Unreachable()
      apply()
    end