json_array.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
use pc = "collections/persistent"

class val JSONArray
  """
  Immutable JSON array backed by a persistent vector.

  Construction is via chained `.push()` calls, each returning a new array
  with structural sharing:

  ```pony
  let arr = JSONArray
    .push(I64(1))
    .push(I64(2))
    .push(I64(3))
  ```
  """

  let _data: pc.Vec[JSONValue]

  new val create(data': pc.Vec[JSONValue] = pc.Vec[JSONValue]) =>
    _data = data'

  fun apply(i: USize): JSONValue ? =>
    """
    Look up a value by index. Raises if out of bounds.
    """
    _data(i)?

  fun size(): USize =>
    """
    Number of elements.
    """
    _data.size()

  fun update(i: USize, value: JSONValue): JSONArray ? =>
    """
    Return a new array with element at index i replaced.
    Raises if out of bounds.
    """
    JSONArray(_data(i)? = value)

  fun push(value: JSONValue): JSONArray =>
    """
    Return a new array with value appended.
    """
    JSONArray(_data.push(value))

  fun pop(): (JSONArray, JSONValue) ? =>
    """
    Return (new array without last element, removed element).
    Raises if empty.
    """
    let last = _data(_data.size() - 1)?
    (JSONArray(_data.pop()?), last)

  fun values(): pc.VecValues[JSONValue] =>
    """
    Iterate over values.
    """
    _data.values()

  fun pairs(): pc.VecPairs[JSONValue] =>
    """
    Iterate over (index, value) pairs.
    """
    _data.pairs()

  fun print(): String iso^ =>
    """
    Compact JSON serialization.
    """
    _JSONPrint.compact_array(this)

  fun pretty_print(indent: String = "  "): String iso^ =>
    """
    Pretty-printed JSON serialization.
    """
    _JSONPrint.pretty_array(this, indent)