ini_map.pony

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
use "collections"

type IniMap is Map[String, Map[String, String]]

primitive IniParse
  """
  This is used to parse INI formatted text as a nested map of strings.
  """
  fun apply(lines: Iterator[String]): IniMap ref^ ? =>
    """
    This accepts a string iterator and returns a nested map of strings. If
    parsing fails, an error is raised.
    """
    let map = IniMap

    let f = object
      let map: IniMap = map

      fun ref apply(section: String, key: String, value: String): Bool =>
        try
          if not map.contains(section) then
            map.insert(section, Map[String, String])
          end
          map(section)?(key) = value
        end
        true

      fun ref add_section(section: String): Bool =>
        if not map.contains(section) then
          map.insert(section, Map[String, String])
        end
        true

      fun ref errors(line: USize, err: IniError): Bool =>
        false
    end

    if not Ini(lines, f) then
      error
    end

    map