command.pony

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
use "collections"

class box Command
  """
  Command contains all of the information describing a command with its spec
  and effective options and arguments, ready to use.
  """
  let _spec: CommandSpec box
  let _fullname: String
  let _options: Map[String, Option] box
  let _args: Map[String, Arg] box

  new _create(
    spec': CommandSpec box,
    fullname': String,
    options': Map[String, Option] box,
    args': Map[String, Arg] box)
  =>
    _spec = spec'
    _fullname = fullname'
    _options = options'
    _args = args'

  fun string(): String iso^ =>
    """
    Returns a representational string for this command.
    """
    let s: String iso = fullname().clone()
    for o in _options.values() do
      s.append(" ")
      s.append(o.deb_string())
    end
    for a in _args.values() do
      s.append(" ")
      s.append(a.deb_string())
    end
    s

  fun spec() : CommandSpec box =>
    """
    Returns the spec for this command.
    """
    _spec

  fun fullname() : String =>
    """
    Returns the full name of this command, with its parents prefixed.
    """
    _fullname

  fun option(name: String): Option =>
    """
    Returns the Option by name, defaulting to a fake Option if unknown.
    """
    try _options(name)? else Option(OptionSpec.bool(name), false) end

  fun arg(name: String): Arg =>
    """
    Returns the Arg by name, defaulting to a fake Arg if unknown.
    """
    try _args(name)? else Arg(ArgSpec.bool(name), false) end

class val Option
  """
  Option contains a spec and an effective value for a given option.
  """
  let _spec: OptionSpec
  let _value: _Value

  new val create(spec': OptionSpec, value': _Value) =>
    _spec = spec'
    _value = value'

  fun _append(next: Option): Option =>
    Option(_spec, _spec._typ_p().append(_value, next._value))

  fun spec() : OptionSpec => _spec

  fun bool(): Bool =>
    """
    Returns the option value as a Bool, defaulting to false.
    """
    try _value as Bool else false end

  fun string(): String =>
    """
    Returns the option value as a String, defaulting to empty.
    """
    try _value as String else "" end

  fun i64(): I64 =>
    """
    Returns the option value as an I64, defaulting to 0.
    """
    try _value as I64 else I64(0) end

  fun u64(): U64 =>
    """
    Returns the option value as an U64, defaulting to 0.
    """
    try _value as U64 else U64(0) end

  fun f64(): F64 =>
    """
    Returns the option value as an F64, defaulting to 0.0.
    """
    try _value as F64 else F64(0) end

  fun string_seq(): ReadSeq[String] val =>
    """
    Returns the option value as a ReadSeq[String], defaulting to empty.
    """
    try
      _value as _StringSeq val
    else
      recover val Array[String]() end
    end

  fun deb_string(): String =>
    _spec.deb_string() + "=" + _value.string()

class val Arg
  """
  Arg contains a spec and an effective value for a given arg.
  """
  let _spec: ArgSpec
  let _value: _Value

  new val create(spec': ArgSpec, value': _Value) =>
    _spec = spec'
    _value = value'

  fun _append(next: Arg): Arg =>
    Arg(_spec, _spec._typ_p().append(_value, next._value))

  fun spec(): ArgSpec => _spec

  fun bool(): Bool =>
    """
    Returns the arg value as a Bool, defaulting to false.
    """
    try _value as Bool else false end

  fun string(): String =>
    """
    Returns the arg value as a String, defaulting to empty.
    """
    try _value as String else "" end

  fun i64(): I64 =>
    """
    Returns the arg value as an I64, defaulting to 0.
    """
    try _value as I64 else I64(0) end

  fun u64(): U64 =>
    """
    Returns the arg value as an U64, defaulting to 0.
    """
    try _value as U64 else U64(0) end

  fun f64(): F64 =>
    """
    Returns the arg value as an F64, defaulting to 0.0.
    """
    try _value as F64 else F64(0) end

  fun string_seq(): ReadSeq[String] val =>
    """
    Returns the arg value as a ReadSeq[String], defaulting to empty.
    """
    try
      _value as _StringSeq val
    else
      recover val Array[String]() end
    end

  fun deb_string(): String =>
    "(" + _spec.deb_string() + "=)" + _value.string()

class val SyntaxError
  """
  SyntaxError summarizes a syntax error in a given parsed command line.
  """
  let _token: String
  let _msg: String

  new val create(token': String, msg': String) =>
    _token = token'
    _msg = msg'

  fun token(): String => _token

  fun string(): String => "Error: " + _msg + " at: '" + _token + "'"